jurus-jurus penghalusan citra – jurus 1 : rata-rata tetangga

05Apr07

Penghalusan citra (Image Smoothing) adalah salah satu teknik meningkatkan fitur tertentu (Enhancement) atau bisa juga digunakan dalam menghilangkan derau (denoising). Tulisan ini akan mengawali implementasi jurus untuk menghaluskan citra ke dalam bahasa object pascal (delphi). Tulisan ini akan merujuk ke tulisan sebelumnya tentang mengakses pixel.

jurus 1 : rata-rata tetangga (mean smoothing)

Jurus ini mengganti nilai pixel (intensitas keabuan atau vektor warna) pada suatu titik dengan nilai pixel pada titik-titik lain yang menjadi tetangga titik tersebut. Pemilihan tetangga yang dijadikan pertimbangan ditentukan dengan membentuk sebuah jendela ketetanggaan berbentuk persegi.

misalkan dimensi jendela adalah nxn maka titik yang disebut tetangga titik P(px, py) adalah titik yang berada dalam jangkauan

(x-mid<= x <=x+mid, y-mid <= y <= y+mid)

dengan mid = n div 2

Definisi di atas dibatasi lagi jika titik yang sedang diproses berada di pinggir citra yaitu titik yang jaraknya dari pinggir citra secara horizontal atau vertikal lebih kecil atau sama dengan mid. Penanganan titik pinggir ini bisa dilakukan dengan mengabaikan tetangga semu (titik di luar dimensi citra) atau dengan mengganti tetangga semu dengan nilai intensitas maksimum atau titik di pinggir seberang (misal tetangga semu titik di pinggir kiri diganti dengan titik di pinggir kanan).

Implementasi dari jurus rata-rata ketetanggan dalam delphi adalah sebagai berikut

function clamp(n:integer; limit:integer=255):integer;
begin
  if (n > limit) then result := limit else
    if (n < 0 ) then result := 0 else result := n;
end;

function citra_smoothing_reratatetangga(input_citra:TBitmap;
            lebar_jendela:integer):TBitmap;
var
  i, j, k, l: integer;
  pb : Array of PArrRGB;
  pb2 : PArrRGB;
  b : TBitmap;
  kmid, sumd : integer;
  rsum, gsum, bsum : real;

  function is_ok(x, y:integer):boolean; begin
    result := (x>=0) and (x < b.Width) 
                and (y >=0) and (y < b.Height)
  end;

begin
  b := input_citra;{ alias, untuk mempersingkat kode }
  Setlength(pb, b.Height);
  for i := 0 to b.Height-1 do
    pb[i] := b.ScanLine[i];

    kmid := lebar_jendela div 2;
    result := TBitmap.Create;
    result.Width := input_citra.Width;
    result.Height := input_citra.Height;
    result.PixelFormat := input_citra.PixelFormat;
    { asumsi format pixel input_citra adalah 24 bit (pf24bit) }

    for j := 0 to b.Height-1 do begin
      pb2 := result.ScanLine[j];
      for i := 0 to b.Width-1 do begin
        rsum := 0;
        gsum := 0;
        bsum := 0;
        sumd := 0;

        for l := -kmid to kmid do
          for k := -kmid to kmid do
            if is_ok(i+k, j+l) then begin 
            { gunakan is_ok untuk mengabaikan tetangga semu }
              rsum := rsum + pb[j+l][i+k].r;
              gsum := gsum + pb[j+l][i+k].g;
              bsum := bsum + pb[j+l][i+k].b;
              sumd := sumd + 1;
            end;

        with pb2[i] do begin
          r := clamp(Round(rsum / sumd));
          g := clamp(Round(gsum / sumd));
          b := clamp(Round(bsum / sumd));
        end;{ with }

      end;{ for i }
    end;{ for j }

  { clean-up }
  Setlength(pb, 0);
end;

Kelebihan dari jurus ini adalah kesederhanaan untuk diimplementasikan. bentuk umum dari perata-rataan di atas adalah konvolusi diskret yang mungkin dibahas di tulisan lain. Kelemahan dari jurus ini adalah berlakunya azas sama rata sama rasa sehingga jika ada ketetanggaan dengan 4 elemen memiliki distribusi yang memiliki struktur tertentu (tangga) misal 2 titik intensitas tinggi bertetangga dengan 2 titik berintensitas rendah (255, 255, 0, 0) maka dengan pemberlakuan jurus ini (lebar jendela 3 atau tetangga terdekat) akan menghasilkan distribusi nilai (255, 128, 128, 0). Hal ini tentunya akan mengganggu jika penghalusan yang digunakan untuk menghilangkan derau (noise) dan hasil dari proses denoising akan dilemparkan ke proses pendeteksian tepi (edge detection) karena proses penghalusan dengan menggunakan rata-rata saja dapat menghilangkan struktur (tepi/sudut).

Filed under: delphi, image processing, programming   |  27 Komentar